QSP - Как сделать?

Aleks Versus Moderator 05.07.2013 07:01 (12 years ago)

Farfignugen:

И в итоге надо получить что бы бойцы сортировались по рейтингу и им присваивались в массив места и все это отображалось как то так.

Как я понял, тебе нужно отсортировать один массив, а позже перетасовать другие массивы соответственно первому. Для этого я специально писал две функции:

Spoiler

! array.sort
$args[0] = $args[0] & ! название сортируемого массива. Может сортировать как текстовые значения, так и числовые
$args[1] = $args[1] & ! параметр, который указывает в какую сторону сортируется массив. 'up' или '' - значения будут располагаться от большего к меньшему 'down' - значения будут располагаться от меньшего к большему.
$args[2] = $replace($args[2],'$') & ! имя массива, в который будут помещены номера элементов исходного массива в порядке сортировки
if $args[3]='': $args[3] = $args[0] & ! имя массива, в который будут помещены результаты сортировки. Т.е. отсортированные значения можно поместить в другой массив, не трогая исходный. Если не указать, результат сортировки будет помещён в исходный массив.
killvar 'easy_math_sort_array'
killvar 'easy_math_copy_array'
if instr($args[0],'$')=1: $args['$']='$' else $args['$']=''
copyarr $args['$']+'easy_math_copy_array',$args[0]
if $args[2]!'':
	args['i']=0
	:for
	if args['i']<arrsize($args['$']+'easy_math_copy_array'):
		easy_math_sort_array[args['i']]=args['i']
		args['i']+=1
		jump 'for'
	end
end
args['i'] = 0
:prohody
if args['i']<arrsize($args['$']+'easy_math_copy_array'):
	args['j']=args['i']
	:sorting
	if args['j']<arrsize($args['$']+'easy_math_copy_array'):
		dynamic "if (<<$args['$']>>easy_math_copy_array[args[0]] < <<$args['$']>>easy_math_copy_array[args[1]] and ($args[2]='' or $args[2]='up')) or (<<$args['$']>>easy_math_copy_array[args[0]] > <<$args['$']>>easy_math_copy_array[args[1]] and $args[2]='down'):
			<<$args['$']>>args['tmp'] = <<$args['$']>>easy_math_copy_array[args[0]]
			<<$args['$']>>easy_math_copy_array[args[0]] = <<$args['$']>>easy_math_copy_array[args[1]]
			<<$args['$']>>easy_math_copy_array[args[1]] = <<$args['$']>>args['tmp']
			if $args[3]!'':
				args['temp'] = easy_math_sort_array[args[0]]
				easy_math_sort_array[args[0]] = easy_math_sort_array[args[1]]
				easy_math_sort_array[args[1]] = args['temp']
			end
		end",args['i'],args['j'],$args[1],$args[2]
		args['j']+=1
		jump 'sorting'
	end
	args['i']+=1
	jump 'prohody'
end
if $args[2]!'': copyarr $args[2],'easy_math_sort_array'
copyarr $args[3],$args['$']+'easy_math_copy_array'
killvar 'easy_math_sort_array'
killvar $args['$']+'easy_math_copy_array'

Не смотри, что громоздко, это только на первый взгляд. На самом деле код, выполняющий сортировку не такой уж и большой. В основном, перед ним, и после, находятся разные проверки и защита от дурака. Следующая программа, используя результаты из первой, переставит элементы других массивов на новые “правильные” места:

Spoiler

! array.retape
$args[0] = $args[0] & ! массив, элементы которого нужно перетасовать
$args[1] = $replace($args[1],'$') & ! массив, в который внесены номера элементов отсортированного массива (в его изначальном варианте) в порядке сортировки.
if $args[2] = '': $args[2] = $args[0] & ! имя массива, в который можно сохранить результат перетасовки. Можно не указывать, тогда результаты сохранятся в исходный массив.
killvar 'easy_math_sort_array'
killvar $args['$']+'easy_math_copy_array'
if instr($args[0],'$')=1: $args['$']='$' else $args['$']=''
copyarr 'easy_math_sort_array',$args[1]
args['i']=0
:for
if args['i'] < arrsize('easy_math_sort_array'):
	dynamic $args['$']+"easy_math_copy_array[args[0]] = "+$args[0]+"[args[1]]",args['i'],easy_math_sort_array[args['i']]
	args['i']+=1
	jump 'for'
end
copyarr $args[2],$args['$']+"easy_math_copy_array"

Теперь для наглядности, пример:

Spoiler

reit[0]=15
reit[1]=10
reit[2]=25
$arm[0]='might'
$arm[1]='sparrow'
$arm[2]='hand'
pow[0]=333
pow[1]=444
pow[2]=55

gs 'array.sort','reit','down','res_array'
! {результат получится такой:
reit[0]=10
reit[1]=15
reit[2]=25
res_array[0]=1
res_array[1]=0
res_array[2]=2
! переставляем элементы в других массивах:}
gs 'array.retape','$arm','res_array'
gs 'array.retape','pow','res_array'
! {результат:
$arm[0]='sparrow'
$arm[1]='might'
$arm[2]='hand'
pow[0]=444
pow[1]=333
pow[2]=55
! res_array теперь можно уничтожить}
killvar 'res_array'

Т.е. был у нас герой с рейтингом 10, и стоял он на второй строчке хитпарада, владел оружием ‘sparrow’ и силой 444, мы переместили его на верхнюю строчку и он сохранил за собой и “оружие” и “силу”. :)

RedFiend #144 05.07.2013 18:00 (12 years ago)

Nex,
Спасибо, я попробую так сделать…
А переменная мне нужна была, что бы сделать предмет численным, как тут быть тогда?

В запасе имеется <<mistloot>> шт.

Nex Moderator 05.07.2013 18:18 (12 years ago)

Тогда вот так:

IF astraluck = 1:
    astraloot = rand(1, 25)
    IF astraloot = 13:
        mistloot = mistloot + 1
        MSG "В результате Ваших действий ..."
        IF NO OBJ "Материя мироздания":
            ADDOBJ "Материя мироздания"
        END
    END
END

Nex Moderator 05.07.2013 18:19 (12 years ago)

RedFiend #144 05.07.2013 18:23 (12 years ago)

Bumbr #465 05.07.2013 20:27 (12 years ago)

Такой вопрос, товарищи.
Пишу под AeroQSP нужно чтобы при нажатии на стрелку в окне основного описания изменялось значение переменной и обновлялось собственно описание.

Spoiler

*pl '<<pSTR>>'
*pl '<<pSPD>>'
*pl '<<pPER>>'
*pl '<<pINT>>'
*pl '<a href="EXEC:pSTR = pSTR + 1"> <img src="img/Вверх.jpg"> </a>'
*pl '<a href="EXEC:pSTR = pSTR - 1"> <img src="img/Вниз.jpg"> </a>'

Пока что он выводит значения переменных, изменяет их по нажатию на стрелки вверх и вниз, но не обновляет значения в окне.
Подвох в том, что не хочется использовать ссылки на действия.

Kraev.Aleks #221 06.07.2013 02:08 (12 years ago)

Bumbr,
Добавь в ссылки переход на эту же самую локацию (gt $curloc). Должно выглядеть примерно так:

*pl '<a href="EXEC:pSTR = pSTR + 1 & gt $curloc"> <img src="img/Вверх.jpg"> </a>' 
*pl '<a href="EXEC:pSTR = pSTR - 1 & gt $curloc"> <img src="img/Вниз.jpg"> </a>'

Bumbr #465 06.07.2013 17:36 (12 years ago)

Нужно сделать таблицу где в первом столбце картинка 80х80 занимающая две строки, а во втором две строки с картинками 40х40

Spoiler

'<table>
<tr>
<td rowspan=2><a href="EXEC: gs $pl, $stattxt, $лицо"> <img src="<<$face>>Face<<face>>.jpg"></a></td>
<td><a href="EXEC: увел = 1 & хар = 5 & gt $curloc"> <img src="<<$int>>Влево.jpg"></a></td>
</tr>
<tr>
<td><a href="EXEC: увел = 0 & хар = 5 & gt $curloc"> <img src="<<$int>>Вправо.jpg"></a></td>
</tr>
</table>'

Приведенный код с точки зрения html вроде правильный, однако вторая картинка 40х40 переносится на следующую строку.

Aleks Versus Moderator 06.07.2013 19:12 (12 years ago)

Bumbr #465 06.07.2013 19:17 (12 years ago)

Edited at 07.07.2013 06:30 (12 years ago)

Byte Admin 08.07.2013 04:08 (12 years ago)

Olegus t.Gl. #12 08.07.2013 05:49 (12 years ago)

Byte:

Здесь проблема в том, что нужно убрать переводы строк (вариант - выводить построчно через *p).
Пробелы непосредственно перед <img> лучше убрать.

Ну это не такая уж большая проблема.
Данный код, оформленный в функцию, убирает переводы строк из текста и пробелы (в начале и в конце каждой строки):

! Присваиваем результату функции значение — переданный текст
	$Result = $ARGS[0]
	:метка_перебор_строк
	! Ищем символ перевода строки
	ARGS[0] = strpos($Result,'\n')
	if ARGS[0]:
		! Если перевод строки найден — вырезаем его
		$Result = trim(mid($Result, 1, ARGS[0] - 1)) + trim(mid($Result, ARGS[0] + 1))
		jump 'метка_перебор_строк'
	end

У меня эта функция называется m2ts. Вызов функции, соответственно, выглядит так: $Текст=m2ts($Текст) или *NL m2ts($Текст). Если убирать пробелы не нужно, то достаточно убрать из кода все вызовы trim().

Byte Admin 08.07.2013 11:08 (12 years ago)

Olegus t.Gl. #12 08.07.2013 11:28 (12 years ago)

F

Farfignugen #908 09.07.2013 19:09 (12 years ago)