QSP - Как сделать?

Byte Admin 12.10.2026 13:52 (1 week ago)

Byte Admin 12.10.2026 13:54 (1 week ago)

mkir #1281 12.10.2026 14:58 (1 week ago)

Byte Admin 12.10.2026 15:32 (1 week ago)

S

Spacum #3989 13.10.2026 18:02 (6 days ago)

mkir:

Byte:

Можно делать и delact ’Взять яблоко’ и delact $selact (последнее удобнее для удаления выбранного действия). DELACT удаляет действие сразу же - дальнейшего перехода на локацию не требуется. С “GT” действие удаляется, происходит переход на локацию и все действия добавляются заново. Если нужен GT, то проще просто не добавлять ACT по какому-то условию.

Хм, тогда не понимаю зачем этот delact нужен. Я думал, он должен удалить действие навсегда. Но возврат на локацию мне как раз нужен - нужны сразу изменения переменных, реакция на изменения, все такое. Есть возможность у перехода в меню и обратно - и если после этого всё будет обновляться, то так не пойдет.

Т.е. по совету Byte и на примере вашего кода: просто надо сделать ’флаг’ обозначающий нужно это действие или нет. И на основе этого выводить или нет act

if flag <> 0:     
    act 'Взять яблоко':
        яблоко+=1
        flag = 0
        gt $curloc
    end
end

Это была проверка на возможность взять только одно яблоко, один раз.

Можно делать проверку на наличие яблок в локации, а можно ли их вообще взять, может их нету и тогда не выводить действие: if яблоко_в_локации > 0:

Можно делать проверку на наличие яблок у персонажа, Может у него они уже есть и ему они не нужны: if яблоко = 0:

Тут хватает вариантов, смотря какой алгоритм и чего вам надо. В общем, “скобки обыкновенные” из простого if … end

Есть вариант “тумблер обыкновенный”. Т.е. при каждом обращении к кнопке он меняет свое значение на противоположное. Наример, представьте у вас пульт с кнопками-лампочками:

нажали - загорелась

нажали - погасла

flag = 1 - flag

Был “0” станет “1”, был “1” станет “0”. Значение меняется при каждом обращении и никаких if .. else .. end

В общем случае такой тумблер описывается так: flag может принимать одно из двух значений А или В тогда формула тумблера выглядит так:

flag = A + B - flag

был равен А станет равен В, был равен В станет равен А

Edited at 13.10.2026 18:20 (6 days ago)

mkir #1281 13.10.2026 21:43 (6 days ago)

Byte Admin 13.10.2026 21:56 (6 days ago)

mkir:

@Spacum Ну, я знаю, как работать с переменными. Вопрос был в том, что у меня этих яблок, груш, фруктов, овощей, гвоздей, табуретов, книг и всего-всего, намечается слишком много - и возможностей что-то подобрать во время какого-нибудь квеста соответственно еще больше, квесты не генерятся, пишутся вручную, единичные, не бесконечные и не рандомные “нычки” расставляются тоже вручную и на каждый “взять” не хочется заводить новую переменную, а хотелось бы просто механически удалять действия после его совершения. Но раз это невозможно в том виде, как мне воображалось, будем по старинке)

Можно сделать через массив:

if act_hidden['Test']=0:
    act 'Test':
        ...
        act_hidden[$selact]=1 &! или act_hidden['Test']=1
        gt $curloc
    end
end

Здесь используется один массив, в котором может сохраняться состояние любого числа действий. Индексом может быть любая строка / название действия / что угодно, в общем-то.

P

provincial #4119 17.10.2026 17:32 (2 days ago)

Снова здравствуйте. Вопрос по html в классическом плеере 5.9, Я с трудом разбирался и сваял такой код:

$up,$left,$right,$down,$upopis,$leftopis,$rightopis,$downopis=%sosed       & ! кортеж который задаётся на каждой локации

'<div align="center">'
'<table border="0" cellpadding="0" cellspacing="0">'
! Первая строка: Наверх
'<tr>'
'  <td width="100"></td>'
if $up <> "":
'    <td align="center" height="20"><a href="EXEC: gt ''<<$up>>''" class="plain"><b><font color="#4a6fa5"><<$upopis>></font></b></a></td>'
else
'    <td height="20"></td>'
end
'  <td width="100"></td>'
'</tr>'
! Вторая строка: Налево и Направо
'<tr>'
if $left <> "":
'    <td align="right" width="100" height="20"><a href="EXEC: gt ''<<$left>>''" class="plain"><b><font color="#4a6fa5"><<$leftopis>></font></b></a></td>'
else
'    <td width="100" height="20"></td>'
end
'  <td width="40"></td>'
if $right <> "":
'    <td align="left" width="100" height="20"><a href="EXEC: gt ''<<$right>>''" class="plain"><b><font color="#4a6fa5"><<$rightopis>></font></b></a></td>'
else
'    <td width="100" height="20"></td>'
end
'</tr>'
! Третья строка: Вниз
'<tr>'
'  <td width="100"></td>'
if $down <> "":
'    <td align="center" height="20"><a href="EXEC: gt ''<<$down>>''" class="plain"><b><font color="#4a6fa5"><<$downopis>></font></b></a></td>'
else
'    <td height="20"></td>'
end
'  <td width="100"></td>'
'</tr>'
'</table>'
'</div>'

Эта локация вызывается через ‘gs’. В итоге у меня навигационный крестик сверху основного окна, тут всё прекрасно работает. Но следом за ним должно идти название текущей локации и её картинка, так вот они почему-то получаются в километре внизу. Экран приходится прокручивать, чтобы до них добраться. Подскажите пожалуйста, как избавиться от этого огромного пробела? Вот пример кода одной из локаций откуда эта ‘tablica’ вызывается:

cls
gs 'time'
$loc =$curloc
y=1
x=1
%sosed=['administr','ploshad','ulicarich','imperpros2','Дума','Главная площадь','Богатая улица','Ниже по проспекту']
gs 'tablica'
'<center><b> Императорский проспект начинающийся от площади перед дворцом </b></center>'
'<center><img src ="" ></center>'
gs 'npconloc'

Первая идея, которая приходит в голову, просто запихать название и картинку в эту же табличку. Но у него как мне показалось есть один минус - я так и не пойму, а что вообще происходит-то.

Также как я второй раз не понял, как надо оформлять сообщения нормально. Мне бы не помешал учебник, по пользованию этим форумом и не на английском.

Edited at 17.10.2026 23:23 (1 day ago)

Byte Admin 18.10.2026 00:05 (1 day ago)

Думаю, это типичная проблема использования неявного оператора: если выводится значение без оператора, то после вывода в основное описание добавляется перенос строки (аналогично *PL). Самое простое решение - использовать явно *P, например:

*p '<center><b> Императорский проспект начинающийся от площади перед дворцом </b></center>'
*p '<center><img src ="" ></center>'

P

provincial #4119 18.10.2026 02:00 (1 day ago)

Aleks Versus Moderator 18.10.2026 09:13 (1 day ago)

В

Вполне себе #2722 19.10.2026 21:12 (1 hour ago)

provincial:

Снова здравствуйте. Вопрос по html в классическом плеере 5.9, Я с трудом разбирался и сваял такой код: …. Эта локация вызывается через ‘gs’. В итоге у меня навигационный крестик сверху основного окна, тут всё прекрасно работает. Но следом за ним должно идти название текущей локации и её картинка, так вот они почему-то получаются в километре внизу. Экран приходится прокручивать, чтобы до них добраться. Подскажите пожалуйста, как избавиться от этого огромного пробела? Вот пример кода одной из локаций откуда эта ‘tablica’ вызывается:

Камрад Байт тебе правильно сказал - при каждом переводе строки у тебя присутствует неявный оператор, а таблица намного короче, ну и ведущие пробелы, они тоже не придают стройности, вот и набегают строки. Попробуй сначала полностью сформировать строку вывода, а затем просто вывести её. Ведущие пробелы убрать!!! Пример можешь посмотреть буквально несколькими страницами ранее. https://qsp.org/forum/23-kak-sdelat?page=436#comment-25722

! Обозначаем как локальную переменную
Local $ResStr

! Обнуляем
$ResStr=''

!Формируем
$ResStr+='<div align="center">'
$ResStr+='<table border="0" cellpadding="0" cellspacing="0">'
! Первая строка: Наверх
$ResStr+='<tr>'
$ResStr+='<td width="100"></td>'
if $up <> "":
    $ResStr+='<td align="center" height="20"><a href="EXEC: gt ''<<$up>>''" class="plain"><b><font color="#4a6fa5"><<$upopis>></font></b></a></td>'
else
    $ResStr+='<td height="20"></td>'
end
$ResStr+='<td width="100"></td>'
$ResStr+='</tr>'
! Вторая строка: Налево и Направо
$ResStr+='<tr>'
if $left <> "":
    $ResStr+='<td align="right" width="100" height="20"><a href="EXEC: gt ''<<$left>>''" class="plain"><b><font color="#4a6fa5"><<$leftopis>></font></b></a></td>'
else
    $ResStr+='<td width="100" height="20"></td>'
end
$ResStr+='<td width="40"></td>'
if $right <> "":
    $ResStr+='<td align="left" width="100" height="20"><a href="EXEC: gt ''<<$right>>''" class="plain"><b><font color="#4a6fa5"><<$rightopis>></font></b></a></td>'
else
    $ResStr+='<td width="100" height="20"></td>'
end
$ResStr+='</tr>'
! Третья строка: Вниз
$ResStr+='<tr>'
$ResStr+='<td width="100"></td>'
if $down <> "":
    $ResStr+='<td align="center" height="20"><a href="EXEC: gt ''<<$down>>''" class="plain"><b><font color="#4a6fa5"><<$downopis>></font></b></a></td>'
else
    $ResStr+='<td height="20"></td>'
end
$ResStr+='<td width="100"></td>'
$ResStr+='</tr>'
$ResStr+='</table>'
$ResStr+='</div>'

! Вывод
$ResStr

Edited at 19.10.2026 21:18 (1 hour ago)