Как сделать?

cla 
if args[0]=0: 
	if Скретч=0: 
		'<font color=green>(Белка) — Эй ты какого х*я ты лезешь в мой дом !?</font>' 
		act'Ты говорящая белка ?!': 
			'<font color=blue>(<<$Имя>>) — <<$selact>></font>' 
			delact $selact 
			'<font color=green>(Белка) — (Вздох)Слушай этот мир полон гномов, эльфов, драконов, магов, а тебя волнует говорящая белка !?</font>' 
			wait 1000 
			if $Пол = 'Мужчина': 
				'<font color=green>(Белка) — Да я умею говорить и мне не нравиться что какой-то урод  лезет прямо ко мне в дом без приглашения !</font>' 
			end 
			if $Пол = 'Женщина': 
				'<font color=green>(Белка) — Да я умею говорить и мне не нравиться что какая-то дура  лезет прямо ко мне в дом без приглашения !</font>' 
			end 
			gs 'Скретч диалог',1 
		end 
		act 'Это ты кидал шишки в меня !': 
			'<font color=blue>(<<$Имя>>) — <<$selact>></font>' 
			delact $selact 
			if $Пол = 'Мужчина': 
				'<font color=green>(Белка) — А ты как хотел? ты же самым наглым образом полез прямо в мой дом!</font>' 
				wait 1000 
			end 
			if $Пол = 'Женщина': 
				'<font color=green>(Белка) — А ты как хотела? ты же самым наглым образом полезла прямо в мой дом!</font>' 
				wait 1000 
			end 
			'<font color=green>(Белка) — Вот я и кинул и кину еще если не прекратишь ибо нехуй !</font>' 
			gs 'Скретч диалог',1 
		end 
	end 
end 

if args[0]=1: 
	if Скретч=0 and Пакет_орехов = 1: 
		act'Попытаться успокоить белку дав ей орехи': 
			'<font color=blue>(<<$Имя>>) - Слушай прости за вторжение, я не знал что тут кто-то живет, и в качестве извинения позволь угостить тебя орехами.' 
			delact $selact 
			set Пакет_орехов = 3 
			DELOBJ 'Пакет орехов' 
			wait 1000 
			'<font color=green>(Белка) — О орешки, мои любимые !, ну ладно прощаю.</font>' 
			wait 500 
			'<font color=green>(Белка) — Тебя как звать то ?</font>' 
			'<font color=blue>(<<$Имя>>) — <<$Имя>>' 
			wait 500 
			'<font color=green>(Белка) — А меня Скретч очень приятно. ?</font>' 
			wait 500 
			'<font color=green>(Скретч) — Ну, ты обращайся, если что нужно будет, где меня найти – уже знаешь.</font>' 
			set Скретч = 1 
			gs 'Скретч диалог',2 
		end 
	end 
end 

if Скретч=0: 
	act 'Попытаться успокоить белку (Харизма)': 
		delact $selact 
		if Харизма => 8: 
			'<font color=blue>(<<$Имя>>)(Харизма УСПЕХ) (Вы прилагаете все усилия, чтобы убедить белку, что вы не враг и не хотели ее обворовать или съесть.)' 
			'<font color=green>(Белка) — Да в красноречии тебе не откажешь, ну ладно верю.</font>' 
			wait 500 
			'<font color=green>(Белка) — Тебя как звать то ?</font>' 
			'<font color=blue>(<<$Имя>>) — <<$Имя>>' 
			wait 500 
			'<font color=green>(Белка) — А меня Скретч очень приятно. ?</font>' 
			wait 500 
			'<font color=green>(Скретч) — Ну, ты обращайся, если что нужно будет, где меня найти – уже знаешь.</font>' 
			set Скретч = 1 
			gs 'Скретч диалог',2 
		end 
		if Харизма < 8: 
			'<font color=blue>(<<$Имя>>) (Харизма НЕУДАЧА) (Вы прилагаете все усилия, чтобы убедить белку, что вы не враг и не хотели ее обворовать или съесть, Но она вам не верит, вам явно недостает харизмы.)' 
			'<font color=green>(Белка) - Че-то не убедил, валика ты отсюда, а то я ребят позову, и тебе мало не покажется.</font>' 
			set Скретч = 2 
			gs 'Скретч диалог',2 
			act 'Да что эта белка может мне сделать ?': gt "Лесная братва" 
			act 'Уйти': gt "Темный лес опушка" 
		end 
	end 
end

если я правильно понимаю, чего ты хочешь добиться. В начале диалога должны появиться три действия:
“ты говорящая белка?”
“это ты кидал шишки в меня?”
“Попытаться успокоить белку (харизма)”
Если есть пакет орехов, то должно появиться четвёртое действие: “успокоить белку, дав ему по орехам орехов”
Первые два действия должны отпадать, когда на них нажимаешь, так? Поэтому для первых двух действий определяем отдельные флаги: флаг_белка_говоришь и флаг_белка_шишки. Если значения этих переменных будут отличаться от нуля, действия выводиться не будут.
Начальный текст должен был выводиться лишь раз, поэтому для него тоже определяем флаг. флаг_белка_начало
Для действия “дать белке орехов” важно, чтобы переменная Пакет_орехов была равна единице. Оставляем только это условие.
Переменная скретч определяет на какой стадии развития находится диалог. Если она равна нулю, выводятся все реплики. Первые два действия выводятся в любом случае, пока их не выполнили, поэтому кроме их “личных” флагов, ничем их вывод не обуславливается.
Действия “успокоить” выводятся пока не выбрано хотя бы одно из них, так? Это событие определяется переменной Скретч. Причём. Если белку удалось успокоить Скретч = 1, а если не удалось Скретч = 2. Если белку успокоить не удалось выводятся два последних действия.
Иными словами, пока скретч = 0 выводятся действия “успокоить”. Если скретч =2 выводятся действия “уйти” и “чё ты мне сделаешь”. Делаем соответствующие условия. И получаем вот такой код:

cla 
if флаг_белка_начало=0:
	'<font color=green>(Белка) — Эй ты какого х*я ты лезешь в мой дом !?</font>'
	флаг_белка_начало=1
end
	if флаг_белка_говоришь=0:
		act'Ты говорящая белка ?!': 
			'<font color=blue>(<<$Имя>>) — <<$selact>></font>' 
			'<font color=green>(Белка) — (Вздох)Слушай этот мир полон гномов, эльфов, драконов, магов, а тебя волнует говорящая белка !?</font>' 
			wait 1000 
			if $Пол = 'Мужчина': 
				'<font color=green>(Белка) — Да я умею говорить и мне не нравиться что какой-то урод  лезет прямо ко мне в дом без приглашения !</font>' 
			end 
			if $Пол = 'Женщина': 
				'<font color=green>(Белка) — Да я умею говорить и мне не нравиться что какая-то дура  лезет прямо ко мне в дом без приглашения !</font>' 
			end
			флаг_белка_говоришь=1
			gs 'Скретч диалог'
		end
	end
	if флаг_белка_шишки = 0:
		act 'Это ты кидал шишки в меня !': 
			'<font color=blue>(<<$Имя>>) — <<$selact>></font>' 
			if $Пол = 'Мужчина': 
				'<font color=green>(Белка) — А ты как хотел? ты же самым наглым образом полез прямо в мой дом!</font>' 
				wait 1000 
			end 
			if $Пол = 'Женщина': 
				'<font color=green>(Белка) — А ты как хотела? ты же самым наглым образом полезла прямо в мой дом!</font>' 
				wait 1000 
			end 
			'<font color=green>(Белка) — Вот я и кинул и кину еще если не прекратишь ибо нехуй !</font>' 
			флаг_белка_шишки = 1
			gs 'Скретч диалог'
		end
	end
if Скретч=0:
	if Пакет_орехов = 1: 
		act'Попытаться успокоить белку дав ей орехи': 
			'<font color=blue>(<<$Имя>>) - Слушай прости за вторжение, я не знал что тут кто-то живет, и в качестве извинения позволь угостить тебя орехами.' 
			Пакет_орехов = 3 
			DELOBJ 'Пакет орехов' 
			wait 1000 
			'<font color=green>(Белка) — О орешки, мои любимые !, ну ладно прощаю.</font>' 
			wait 500 
			'<font color=green>(Белка) — Тебя как звать то ?</font>' 
			'<font color=blue>(<<$Имя>>) — <<$Имя>>' 
			wait 500 
			'<font color=green>(Белка) — А меня Скретч очень приятно. ?</font>' 
			wait 500 
			'<font color=green>(Скретч) — Ну, ты обращайся, если что нужно будет, где меня найти – уже знаешь.</font>' 
			Скретч = 1 
			gs 'Скретч диалог'
		end 
	end 
	act 'Попытаться успокоить белку (Харизма)': 
		if Харизма => 8: 
			'<font color=blue>(<<$Имя>>)(Харизма УСПЕХ) (Вы прилагаете все усилия, чтобы убедить белку, что вы не враг и не хотели ее обворовать или съесть.)' 
			'<font color=green>(Белка) — Да в красноречии тебе не откажешь, ну ладно верю.</font>' 
			wait 500 
			'<font color=green>(Белка) — Тебя как звать то ?</font>' 
			'<font color=blue>(<<$Имя>>) — <<$Имя>>' 
			wait 500 
			'<font color=green>(Белка) — А меня Скретч очень приятно. ?</font>' 
			wait 500 
			'<font color=green>(Скретч) — Ну, ты обращайся, если что нужно будет, где меня найти – уже знаешь.</font>' 
			Скретч = 1 
			gs 'Скретч диалог'
		end 
		if Харизма < 8: 
			'<font color=blue>(<<$Имя>>) (Харизма НЕУДАЧА) (Вы прилагаете все усилия, чтобы убедить белку, что вы не враг и не хотели ее обворовать или съесть, Но она вам не верит, вам явно недостает харизмы.)' 
			'<font color=green>(Белка) - Че-то не убедил, валика ты отсюда, а то я ребят позову, и тебе мало не покажется.</font>' 
			Скретч = 2 
			gs 'Скретч диалог' 
		end 
	end 
end
if Скретч=2:
	act 'Да что эта белка может мне сделать ?': gt "Лесная братва" 
	act 'Уйти': gt "Темный лес опушка"
end